No tento script zapne IP, GATEWAY, a nastavi kanal a ssi na AP1. Hned potom posle 5 pingov na IP APcka1.Ak sa ani jeden nevrati vypne IP, GATEWAY pre AP1, zapne GATEWAY, IP a nastavi ssid a kanal pre AP2. Je tam nevyhoda ze kym prebieha kontrola pingu na AP1 a AP1 nieje stale dostupne tak nejde net. Mozno ti to aspon trosku pomoze
Pozor: script uz nekontroluje po prehodeni na AP2 dostupnost AP2.
#zadefinovanie ssid a frekvencie pre jednotlive AP
:set ssidAP1 ("tu_zadat_ssid_AP1")
:set frequencyAP1 ("tu_zadat_frekvenciu_AP1")
:set ssidAP2 ("tu_zadat_ssid_AP2")
:set frequencyAP2 ("tu_zadat_frekvenciu_AP2")
#zadefinovanie IP adresy na ktoru sa ma overovat spojenie na AP1
:set ip ("tu_zadat_ip_AP1_na_ktoru_sa_bude_kontrolovat_dostupnostAP1")
#zadefinovanie nazvu bran
:set gwAP1 ("default_gw_AP1")
:set gwAP2 ("default_gw_AP2")
#zadefinovanie nazvu IP adries
:set ipAP1 ("IP-AP1")
:set ipAP2 ("IP-AP2")
#vychodzie AP je AP1 takze defaultne nastavime vsetko na AP1
/interface wireless set Internet ssid=$ssidAP1 frequency=$frequencyAP1
:log info ("Menim ssid na (" . $ssidAP1 . ") a frekvenciu na (" . $frequencyAP1 . " MHz)")
#vypneme gw pre AP2
/ip route {disable [find comment=$gwAP2]}
#zapneme gw pre AP1
/ip route {enable [find comment=$gwAP1]}
#vypneme IP pre AP2
/ip address {disable [find comment=$ipAP2]}
#zapneme IP pre AP1
/ip address {enable [find comment=$ipAP1]}
:delay 2
#skontrolujeme dostupnost AP1
:if ([/ping $ip count=5] != 5 ) do={
:log info (" Ping na " . $ssidAP1 . " neuspesny ")
#ak nieje dostupne AP1 zmenime nastavenia na AP2
/interface wireless set Internet ssid=$ssidAP2 frequency=$frequencyAP2
:log info (" Menim ssid na (" . $ssidAP2 . ") a frekvenciu na (" . $ferquencyAP2 . " MHz)")
/ip route {
disable [find comment=$gwAP1]
:log info ("Vypinam gw pre AP1")
}
/ip route {
enable [find comment=$gwAP2]
:log info ("Zapinam gw pre AP2")
}
/ip address {
disable [find comment=$ipAP1]
:log info ("Vypinam ip pre AP1")
}
/ip address {
enable [find comment=$ipAP2]
:log info ("Zapinam ip pre AP2")
}
}
ak budes mat este nejake otazky tak sa pytaj tu alebo na ICQ: 200290906
